// _root
// フレームアクション
var my0_str = 1;  // 接尾辞は型指定と無関係→エラーなし
var my1_str:String = my0_str;  // 右辺の値が型指定なし
var my1_str:String = 1;  // ストリング型指定変数に数値代入→エラー

// 第1フレームアクション
var my_str:String = "string";

// 第2フレームアクション
var nMyNumber:Number = my_str; � // エラーなし

var my_txt:TextField; � // TextField型指定
var nMyNumber1:Number = my_txt.text; � // 上記指定なければエラーなし
var nMyNumber2:Number = _root; � // タイムラインは型指定されている→エラー

trace(this); �// 出力: _level0
var nMyNumber3:Number = this; � // thisは型指定されない→エラーなし
var my_str:String = "string";
var nMyNumber4:Number = this.my_str;  // 型指定のないインスタンスのプロパティは型を調べない→エラーなし

// MovieClipアクション
// function.fla
onClipEvent (load) {
  // 関数getAngle: xy座標から角度を度数で返す
  // 引数: nX:x座標(数値), nY:y座標(数値)
  // 戻り値: 度数(数値)
  function getAngle(nX:Number, nY:Number):Number {
    var nRadian:Number = Math.atan2(nY, nX);
    return nRadian/Math.PI*180;
  }
}
onClipEvent (mouseUp) {
  trace(getAngle(_xmouse, _ymouse));
}

// ButtonまたはMovieClipアクション
// TextFieldインスタンス_root.my_txtを配置
on (release) {
  if (!_root.my_txt.text) {  // 文字列が空(長さ0)の場合
    _root.my_txt.text = "No entry!";
  }
}

// MovieClip: マウスポインタに向かって回転するインスタンス
// MovieClipアクション
onClipEvent (load) {
  // 初期設定
  var deceleration:Number = 0.2;
  // 関数定義
  function rotateTo(nRelativeRotation:Number):Void {
    _rotation += nRelativeRotation;
  }
  function getAngle(nX:Number, nY:Number):Number {
    var nRadian:Number = Math.atan2(nY, nX);
    return nRadian/Math.PI*180;
  }
}
onClipEvent (enterFrame) {  // アニメーション処理
  var nRelativeRotation:Number = getAngle(_xmouse, _ymouse);
  rotateTo(nRelativeRotation*deceleration);
}

// MovieClip: マウスポインタの方向に回転するインスタンス
// 第1フレームアクション
// 初期設定
var deceleration:Number = 0.2;
// 関数定義 function rotateTo(nRelativeRotation:Number):Void {
  _rotation += nRelativeRotation;
}
function getAngle(nX:Number, nY:Number):Number {
  var nRadian:Number = Math.atan2(nY, nX);
  return nRadian/Math.PI*180;
}
this.onEnterFrame = function() {  // イベントハンドラメソッド定義
  var nRelativeRotation:Number = getAngle(_xmouse, _ymouse);
  rotateTo(nRelativeRotation*deceleration);
};

// MovieClipシンボル: リンケージ識別子"Pen"
// MovieClip: マウスポインタの方向に回転するインスタンス
// 第1フレームアクション
#initclip
function Rotation() {  // コンストラクタ関数
}
Rotation.prototype = new MovieClip();  // MovieClipクラスを継承
Rotation.prototype.deceleration = 0.2;
// メソッド定義
Rotation.prototype.rotateTo = function(nRelativeRotation) {
  this._rotation += nRelativeRotation;
};
Rotation.prototype.getAngle = function(nX, nY) {
  var nRadian = Math.atan2(nY, nX);
  return nRadian/Math.PI*180;
};
Rotation.prototype.onEnterFrame = function() {
  var nRelativeRotation = this.getAngle(this._xmouse, this._ymouse);
  this.rotateTo(nRelativeRotation*this.deceleration);
};
// シンボルへのクラス登録
Object.registerClass("Pen", Rotation);
#endinitclip

// ActionScript 2.0クラス定義ファイル: Rotation.as
class Rotation extends MovieClip {  // クラス定義: MovieClipクラスを継承
  // プロパティ宣言
  var deceleration:Number = 0.2;
  // メソッド定義
  function rotateTo(nRelativeRotation:Number):Void {
    _rotation += nRelativeRotation;
  }
  function getAngle(nX:Number, nY:Number):Number {
    var nRadian:Number = Math.atan2(nY, nX);
    return nRadian/Math.PI*180;
  }
  function onEnterFrame() {
    var nRelativeRotation:Number = getAngle(_xmouse, _ymouse);
    rotateTo(nRelativeRotation*deceleration);
  }
}