// フレームアクション
var my_mc:MovieClip;
var my_mcl:MovieClipLoader = new MovieClipLoader();
my_mcl.onLoadInit = function(target_mc:MovieClip) {
  trace(target_mc);
};
my_mcl.loadClip("test.swf", my_mc);

**エラー** シーン = シーン 1, レイヤー = Scripts, フレーム = 1 :行 4:onLoadInit' という名前のプロパティはありません。 my_mcl.onLoadInit = function(target_mc:MovieClip) {

[*1]Classesフォルダ
オペレーティングシステムごとの具体的なフォルダのパスについては、Flash MX 2004オンラインヘルプの[ActionScriptリファレンスガイド] >[ActionScript 2.0によるクラスの作成] > [クラスパスについて] > [グローバルなクラスパスとドキュメントレベルのクラスパス]をご参照ください。

//****************************************************************************
// ActionScript Standard Library
// MovieClipLoader object
//****************************************************************************

intrinsic class MovieClipLoader
{
  function MovieClipLoader();

  function addListener(listener:Object):Boolean;
  function getProgress(target:Object):Object;
  function loadClip(url:String, target:Object):Boolean;
  function removeListener(listener:Object):Boolean;
  function unloadClip(target:Object):Boolean;

  function onLoadComplete(target:Object):Void;
  function onLoadError(target:Object, errorCode:String):Void;
  function onLoadProgress(target:Object, bytesLoaded:Number, bytesTotal:Number):Void;
  function onLoadStart(target:Object):Void;
}

[*2]intrinsicクラス内のメソッド定義
MovieClipLoaderのintrinsicクラス定義ファイルには、他のイベントハンドラメソッド(たとえば、MovieClipLoader.onLoadCompleteやMovieClipLoader.onLoadError)は定義されています。これらのイベントハンドラメソッドについても、MovieClipLoaderインスタンスに直接定義することは問題です。

したがって、MovieClipLoader.onLoadInitメソッドだけがintrinsicクラス定義から漏れているのは、一種のバグというべきです。インスタンスへの直接定義を警告するためにMovieClipLoaderクラス定義から外すのであれば、他のイベントハンドラメソッドも同様に削除すべきでしょう。

// フレームアクション
var my_mc:MovieClip;
var my_mcl:MovieClipLoader = new MovieClipLoader();
var oListener:Object = new Object();
oListener.onLoadInit = function(target_mc:MovieClip) {
  trace(target_mc);
};
my_mcl.addListener(oListener);
my_mcl.loadClip("test.swf", my_mc);