// フレームアクション
//[1]Soundインスタンス生成
var my_sound:Sound = new Sound();
//[2]ボリュームを0に設定
var nVolume:Number = 0;
my_sound.setVolume(nVolume);
//[3]ストリーミングサウンドのロード
my_sound.loadSound("test.mp3", true);
trace(my_sound.getVolume()); // テスト用
//[4]フェードイン
this.onEnterFrame = function() {
  nVolume += 5; // ボリュームアップ
  if (nVolume>=100) { // 100%に達したら
    // ボリュームを100%に設定
    my_sound.setVolume(100);
    // フェードイン処理クリア
    delete this.onEnterFrame;
  } else { // 100%未満なら
    // ボリューム設定
    my_sound.setVolume(nVolume);
  }
  trace(my_sound.getVolume()); // テスト用
};

[*1] Sound.loadSound()メソッドを使った外部MP3のロードと再生については、「Sound.loadSound()メソッド」および「Sound.loadSoundメソッドでイベントサウンドを読込んで再生する」をご参照ください。。

// フレームアクション
//[1]Soundインスタンス生成
var my_sound:Sound = new Sound(this);  // ターゲットを指定
//[2]ボリュームの初期値を0に設定
var nVolume:Number = 0;
// my_sound.setVolume(100); // ボリューム設定が変動する可能性のあるときは100に戻す
//[3]ストリーミングサウンドのロード
my_sound.loadSound("test.mp3", true);
//[4]ボリュームを設定【ロード開始後】
my_sound.setVolume(nVolume);
trace(my_sound.getVolume()); // テスト用
//[5]フェードイン
this.onEnterFrame = function() {
  nVolume += 5; // ボリュームアップ
  if (nVolume>=100) { // 100%に達したら
    // ボリュームを100%に設定
    my_sound.setVolume(100);
    // フェードイン処理クリア
    delete this.onEnterFrame;
  } else { // 100%未満なら
    // ボリューム設定
    my_sound.setVolume(nVolume);
  }
  trace(my_sound.getVolume()); // テスト用
};

[*2] 今回の問題の場合にも、ロード後のSound.getVolume()メソッドの戻り値は100にリセットされます。しかし、実際のボリュームは、事前の音量のまま変化しません。つまり、その音量をボリューム100の状態と誤認してしまうことが、問題の原因となっているようです。

したがって、事前のボリュームを10に設定すると、音が聴こえなくなる現象は生じないものの、ボリュームを100に戻しても10の音量でしか再生されない状態になります。ですから、外部MP3サウンドロード前のボリュームの値は、100に設定しておくことが確実といえます。