サイトトップ

Director Flash 書籍 業務内容 プロフィール

Adobe Flash非公式テクニカルノート

Starlingフレームワークでビットマップ上のクリックを検知する

ID: FN1205003 Product: Flash CS5 and above Platform: All Version: 11 and above/ActionScript 3.0

Starlingフレームワークでインスタンスをクリックする」では、インスタンスの上でマウスクリックしたことをDisplayObject.touchイベント(定数TouchEvent.TOUCH)とDisplayObject.hitTest()メソッドの組合わせにより確かめました。ただし、DisplayObject.hitTest()メソッドは、ポインタとの重なりをインスタンスの矩形領域で調べます。本稿では、ビットマップについてマウスクリックをその形状で検知してみます。


01 ビットマップのインスタンスをクリックする
まずは、[ライブラリ]のビットマップからつくったインスタンスをステージに置いて、インスタンスにDisplayObject.touchイベントのリスナーメソッドを加えます。ビットマップには[ライブラリ]で、予めクラスを設定しておきます(図001)。

図001■[ライブラリ]のビットマップにクラスを設定する
図001

以下のスクリプト001は、ステージに置かれたインスタンスをクリックするたびに、下に5ピクセルずつ動かします。クリックするのがビットマップイメージをもったImageインスタンスであることを除いて[*1]、マウスクリックの扱いは前出「Starlingフレームワークでインスタンスをクリックする」のスクリプト002と同じです。

スクリプト001■ビットマップイメージが含まれたインスタンスをクリックするたびに下に動かす
    // ActionScript 3.0クラス定義ファイル: MySprite.as
  1. package {
  2.   import flash.display.BitmapData;
  3.   import flash.geom.Point;
  4.   import starling.display.DisplayObject;
  5.   import starling.display.Sprite;
  6.   import starling.display.Image;
  7.   import starling.textures.Texture;
  8.   import starling.events.Event;
  9.   import starling.events.TouchEvent;
  10.   import starling.events.Touch;
  11.   import starling.events.TouchPhase;
  12.   public class MySprite extends Sprite {
  13.     private var myBitmapData:BitmapData;
  14.     public function MySprite() {
  15.       addEventListener(Event.ADDED_TO_STAGE, initialize);
  16.     }
  17.     private function initialize(eventObject:Event):void {
  18.       myBitmapData = new Pen();
  19.       var myTexture:Texture = Texture.fromBitmapData(myBitmapData);
  20.       var ball:Image = new Image(myTexture);
  21.       addChild(ball);
  22.       ball.x = (stage.stageWidth - myTexture.width) / 2;
  23.       ball.y = (stage.stageHeight - myTexture.height) / 2;
  24.       ball.addEventListener(TouchEvent.TOUCH, dispatchMouseEvent);
  25.     }
  26.     private function onClick(eventObject:TouchEvent):void {
  27.       var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  28.       instance.y += 5;
  29.     }
  30.     private function dispatchMouseEvent(eventObject:TouchEvent):void {
  31.       var myTouch:Touch = eventObject.getTouch(stage, TouchPhase.ENDED);
  32.       if (myTouch) {
  33.         var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  34.         var myPoint:Point = myTouch.getLocation(instance);
  35.         if (instance.hitTest(myPoint, true)) {
  36.           onClick(eventObject);
  37.         }
  38.       }
  39.     }
  40.   }
  41. }

DisplayObject.hitTest()メソッドは、引数に渡されたPointオブジェクトの座標とインスタンスとの重なりを、インスタンスの矩形領域にもとづいて調べます(スクリプト001第34〜35行目)。ですから、前出「Starlingフレームワークでインスタンスをクリックする」で試したQuadインスタンスのように、イメージが矩形でしたらこのスクリプト001で問題ありません。けれど、ビットマップが矩形でないときは、イメージの外でも矩形領域の中ならマウスクリックを受止めてしまいます(図001)。

  1. var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  2. var myPoint:Point = myTouch.getLocation(instance);
  3. if (instance.hitTest(myPoint, true)) {
  4.   onClick(eventObject);
  5. }

図002■ポインタがイメージ上になくても矩形領域内ならクリックできてしまう
図002

[*1] [ライブラリ]のビットマップからTextureをつくって、Imageインスタンスとして配置するやり方については、「StarlingフレームワークでつくったテクスチャのボールをBox2Dで弾ませる」の01「テクスチャでボールをつくる」をお読みください。


02 BitmapData.hitTest()メソッドで座標との重なりを調べる
ActionScript 3.0定義済みのBitmapData.hitTest()メソッドを用いると、ビットマップイメージのアルファを識別した重なりが確かめられます。つまり、アルファを抜いた部分は、重なりの範囲から除くことができるのです。BitmapData.hitTest()メソッドは、つぎのような3つの構文でBitmapDataインスタンスとの重なりが調べられます。

  1. BitmapDataオブジェクト.hitTest(左上角Pointオブジェクト, アルファしきい値, 対象PointまたはRectangleオブジェクト)
  2. BitmapDataオブジェクト.hitTest(左上角Pointオブジェクト, アルファしきい値, 対象Bitmapオブジェクト)
  3. BitmapDataオブジェクト.hitTest(左上角Pointオブジェクト, アルファしきい値, 対象BitmapDataオブジェクト, 対象左上角Pointオブジェクト, 対象アルファしきい値)

いずれも、第1引数はインスタンスが配置された右上角を定めるPointオブジェクトで、第2引数がイメージの領域に含めるアルファのしきい値です。そして、第3引数には座標情報をPointまたはRectangleオブジェクトで示すか、対象とするBitmapまたは BitmapDataインスタンスを渡します(表001)。今回は、マウスポインタの座標をPointオブジェクトにして調べます。

表001■BitmapData.hitTest()メソッド
BitmapDataクラス
パッケージ flash.display
継承 BitmapData → Object
hitTest()メソッド
文法 public function hitTest(firstPoint:Point, firstAlphaThreshold:uint, secondObject:Object, secondBitmapDataPoint:Point = null, secondAlphaThreshold:uint = 1):Boolean
概要

参照するBitmapDataインスタンスと他のインスタンスとのピクセル単位の接触を、ブール(論理)値の判定結果として返す。接触を判定する対象となるのは、PointかRectangle、あるいは他のBitmapまたはBitmapDataインスタンス。

引数

firstPoint:Point − 配置された座標空間におけるBitmapDataインスタンスの左上角座標を示すPointインスタンス。

firstAlphaThreshold:uint − 参照するBitmapDataインスタンス上で接触の判定対象に含めるアルファの最低値(しきい値)を示す0から255までの整数。

secondObject:Object − 判定対象とするPoint、Rectangle、Bitmapまたは BitmapDataインスタンス。

secondBitmapDataPoint:Point − 前引数secondObjectの判定対象がBitmapDataインスタンスのとき、その左上隅座標を示すPointインスタンス。デフォルトはnull(指定なし)。

secondAlphaThreshold:uint − 前引数secondObjectの判定対象がBitmapDataインスタンスのとき、そのオブジェクト上で接触の判定対象に含めるアルファの最低値(しきい値)を示す0から255までの整数。デフォルト値は1。

戻り値 重なっているかどうかを示すブール値。

このBitmapData.hitTest()メソッドを使うため、実はすでに前掲スクリプト001では、BitmapDataインスタンスをローカル変数でなくプロパティに納めておきました(第13および第18行目)[*2]

  1. private var myBitmapData:BitmapData;
  1. private function initialize(eventObject:Event):void {
  2.   myBitmapData = new Pen();
  1. }

マウスポインタがビットマップイメージ上にあるかどうかを調べるメソッドは別に定めます(instanceIsTouched())。Imageインスタンスとマウスポインタの座標をそれぞれ調べるため、引数にはImage(DisplayObject)とTouchのオブジェクトを渡します(第35および第40〜44行目)。メソッドの戻り値は、座標が重なっているかどうかを示すブール(論理)値です。クラス定義(MySprite)全体はスクリプト002として後に掲げます。つぎの抜書きの行番号は、スクリプト002にもとづいています。

  1.     private var zeroPoint:Point = new Point(0, 0);
  1. private function dispatchMouseEvent(eventObject:TouchEvent):void {
  2.   var myTouch:Touch = eventObject.getTouch(stage, TouchPhase.ENDED);
  3.   if (myTouch) {
  4.     var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
        // var myPoint:Point = myTouch.getLocation(instance);
        // if (instance.hitTest(myPoint, true)) {
  5.     if (instanceIsTouched(instance, myTouch)) {
  6.       onClick(eventObject);
  7.     }
  8.   }
  9. }
  10.     private function instanceIsTouched(instance:DisplayObject, myTouch:Touch):Boolean {
  11.       var mousePoint:Point = myTouch.getLocation(instance);
  12.       var touched:Boolean = myBitmapData.hitTest(zeroPoint, 0x0, mousePoint);
  13.       return touched;
  14.     }

引数のImage(DisplayObject)とTouchのオブジェクトから、Touch.getLocation()メソッドでインスタンス上のマウス座標をPointオブジェクトで得ました(第40〜41行目)。BitmapData.hitTest()メソッドの第3引数にはこのインスタンスから見たマウス座標を渡しますので、第1引数のインスタンスの左上角は原点(0, 0)でよいことになります。第2引数のしきい値は、アルファが完全に抜けた0x0(0)としました(第42行目)。なお、原点のPointオブジェクトは、予めプロパティ(zeroPoint)に納めました(第14行目)。そして、BitmapData.hitTest()メソッドの戻り値を返します(第43行目)。

スクリプト002■マウスボタンを放した座標がイメージ上かどうかをBitmapData.hitTest()メソッドで調べる
    // ActionScript 3.0クラス定義ファイル: MySprite.as
  1. package {
  2.   import flash.display.BitmapData;
  3.   import flash.geom.Point;
  4.   import starling.display.DisplayObject;
  5.   import starling.display.Sprite;
  6.   import starling.display.Image;
  7.   import starling.textures.Texture;
  8.   import starling.events.Event;
  9.   import starling.events.TouchEvent;
  10.   import starling.events.Touch;
  11.   import starling.events.TouchPhase;
  12.   public class MySprite extends Sprite {
  13.     private var myBitmapData:BitmapData;
  14.     private var zeroPoint:Point = new Point(0, 0);
  15.     public function MySprite() {
  16.       addEventListener(Event.ADDED_TO_STAGE, initialize);
  17.     }
  18.     private function initialize(eventObject:Event):void {
  19.       myBitmapData = new Pen();
  20.       var myTexture:Texture = Texture.fromBitmapData(myBitmapData);
  21.       var ball:Image = new Image(myTexture);
  22.       addChild(ball);
  23.       ball.x = (stage.stageWidth - myTexture.width) / 2;
  24.       ball.y = (stage.stageHeight - myTexture.height) / 2;
  25.       ball.addEventListener(TouchEvent.TOUCH, dispatchMouseEvent);
  26.     }
  27.     private function onClick(eventObject:TouchEvent):void {
  28.       var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  29.       instance.y += 5;
  30.     }
  31.     private function dispatchMouseEvent(eventObject:TouchEvent):void {
  32.       var myTouch:Touch = eventObject.getTouch(stage, TouchPhase.ENDED);
  33.       if (myTouch) {
  34.         var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  35.         if (instanceIsTouched(instance, myTouch)) {
  36.           onClick(eventObject);
  37.         }
  38.       }
  39.     }
  40.     private function instanceIsTouched(instance:DisplayObject, myTouch:Touch):Boolean {
  41.       var mousePoint:Point = myTouch.getLocation(instance);
  42.       var touched:Boolean = myBitmapData.hitTest(zeroPoint, 0x0, mousePoint);
  43.       return touched;
  44.     }
  45.   }
  46. }

これでマウスボタンを放したことが、インスタンスの矩形領域ではなく、実際のビットマップイメージの上かどうかで検知されます。矩形領域内でもイメージがない位置では、インスタンスはクリックとして受取りません(前掲図002参照)。

[*2] Starlingフレームワークにおいて、ビットマップイメージのデータはTextureオブジェクトがもちます。ですから、今回のようにBitmapDataインスタンスを使う必要がなければ、ローカル変数に納めてメモリは開放するのが望ましいでしょう。

なお、BitmapData.dispose()メソッドは、ビットマップイメージのデータをオブジェクトから直ちに消し去ります。ただし、データを失ったBitmapDataオブジェクトそのものは残りますので、ガベージコレクションにかけます。


03 マウスボタンを押す操作も確かめる
前掲スクリプト002で、アルファを見切ったイメージ上のマウスクリックはとれているように感じられます。けれど、ひとつ穴があります。アルファの抜けた矩形領域内でマウスボタンを押し、イメージ上で放したときクリックと扱われてしまうのです(図003)。

図003■矩形領域内でマウスボタンを押してイメージ上で放すとクリックになる
図003

インスタンスの矩形領域内でマウスボタンを押せば、DisplayObject.touchイベントが起こってしまいます(Touch.phaseプロパティの値はTouchPhase.BEGAN)。すると、マウスボタンを放したときのポインタ座標を調べただけでは、この問題はさけられません。つまり、マウスボタンを押したときも、ポインタがイメージ上にあるかどうか確かめなければならないのです。

そこで、つぎのような修正を加えます(行番号は後掲スクリプト003にもとづきます)。DisplayObject.touchイベントのリスナーメソッド(dispatchMouseEvent())で、扱いたいTouch.phaseプロパティの値がTouchPhase.BEGANTouchPhase.ENDEDのふたつになりましたので、TouchEvent.getTouch()メソッドの第2引数は与えずにTouchオブジェクトを取出します(第33行目)。

Touch.phaseプロパティの値がTouchPhase.BEGANのとき(第37行目)、マウスポインタがビットマップイメージ上にあるかどうかを調べます(第38行目)。イメージ上であれば、フラグとしてvar宣言したプロパティ(pressed)をtrueにします(第39行目)。なお、プロパティの初期値はfalseです(第15行目)。

Touch.phaseプロパティの値がTouchPhase.ENDEDになったら(第42行目)、マウスポインタがイメージ上にあるだけでなく、フラグのプロパティ(pressed)はtrueであることを確かめてクリックとして扱います(第43〜44行目)。その後、プロパティの値はfalseに戻します(第46行目)。

  1. private var pressed:Boolean = false;
  1. private function dispatchMouseEvent(eventObject:TouchEvent):void {
      // var myTouch:Touch = eventObject.getTouch(stage, TouchPhase.ENDED);
  2.   var myTouch:Touch = eventObject.getTouch(stage);
  3.   if (myTouch) {
  4.     var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  5.     switch (myTouch.phase) {
  6.       case TouchPhase.BEGAN:
  7.         if (instanceIsTouched(instance, myTouch)) {
  8.           pressed = true;
  9.         }
  10.         break;
  11.       case TouchPhase.ENDED:
  12.         if (pressed && instanceIsTouched(instance, myTouch)) {
  13.           onClick(eventObject);
  14.         }
  15.         pressed = false;
  16.         break;
  17.     }
  18.   }
  19. }

これで、ビットマップイメージのアルファを識別したクリックが正しく捉えられます。Starlingフレームワークのルートクラス(MySprite)全体は、つぎのスクリプト003のとおりです。

スクリプト003■ビットマップイメージのアルファまで識別してクリックを捉える
    // ActionScript 3.0クラス定義ファイル: MySprite.as
  1. package {
  2.   import flash.display.BitmapData;
  3.   import flash.geom.Point;
  4.   import starling.display.DisplayObject;
  5.   import starling.display.Sprite;
  6.   import starling.display.Image;
  7.   import starling.textures.Texture;
  8.   import starling.events.Event;
  9.   import starling.events.TouchEvent;
  10.   import starling.events.Touch;
  11.   import starling.events.TouchPhase;
  12.   public class MySprite extends Sprite {
  13.     private var myBitmapData:BitmapData;
  14.     private var zeroPoint:Point = new Point(0, 0);
  15.     private var pressed:Boolean = false;
  16.     public function MySprite() {
  17.       addEventListener(Event.ADDED_TO_STAGE, initialize);
  18.     }
  19.     private function initialize(eventObject:Event):void {
  20.       myBitmapData = new Pen();
  21.       var myTexture:Texture = Texture.fromBitmapData(myBitmapData);
  22.       var ball:Image = new Image(myTexture);
  23.       addChild(ball);
  24.       ball.x = (stage.stageWidth - myTexture.width) / 2;
  25.       ball.y = (stage.stageHeight - myTexture.height) / 2;
  26.       ball.addEventListener(TouchEvent.TOUCH, dispatchMouseEvent);
  27.     }
  28.     private function onClick(eventObject:TouchEvent):void {
  29.       var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  30.       instance.y += 5;
  31.     }
  32.     private function dispatchMouseEvent(eventObject:TouchEvent):void {
  33.       var myTouch:Touch = eventObject.getTouch(stage);
  34.       if (myTouch) {
  35.         var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  36.         switch (myTouch.phase) {
  37.           case TouchPhase.BEGAN:
  38.             if (instanceIsTouched(instance, myTouch)) {
  39.               pressed = true;
  40.             }
  41.             break;
  42.           case TouchPhase.ENDED:
  43.             if (pressed && instanceIsTouched(instance, myTouch)) {
  44.               onClick(eventObject);
  45.             }
  46.             pressed = false;
  47.             break;
  48.         }
  49.       }
  50.     }
  51.     private function instanceIsTouched(instance:DisplayObject, myTouch:Touch):Boolean {
  52.       var mousePoint:Point = myTouch.getLocation(instance);
  53.       var touched:Boolean = myBitmapData.hitTest(zeroPoint, 0x0, mousePoint);
  54.       return touched;
  55.     }
  56.   }
  57. }

04 複数のマウスインタラクションを扱う
まとめとして、複数のマウスインタラクションに動きを与えましょう。具体的には、インスタンス上でマウスボタンを押したときと放したとき(クリック)、インスタンス外で放したときの都合3つです。3つの操作に対するインスタンスのふるまいは、それぞれメソッドとして定めます。

  1. インスタンス上でマウスボタンを押したとき(onPress())
    • インスタンスのアルファを下げる。
  2. インスタンス上でマウスボタンを放したとき(onClick())
    • インスタンスの位置を下げて、アルファは戻す。
  3. インスタンス外でマウスボタンを放したとき(onReleaseOutside())
    • インスタンスのアルファを戻す。

3つの操作を扱うメソッドには、いずれも引数としてイベントオブジェクトを渡します。すると、イベントオブジェクトから操作対象のインスタンス(Event.currentTargetプロパティ)を取出すことが求められます。そこで、前掲スクリプト003を先に整理しておきましょう。

つぎのように新たに定めるメソッド(getInstance())で、引数のイベントオブジェクトから操作対象のインスタンスを返すことにします(第56〜59行目)。そこで、マウスポインタがビットマップイメージ上にあるかどうかを調べるメソッド(instanceIsTouched())も、引数にイベントオブジェクトを受取るように変えました(第51行目)。DisplayObject.touchイベントのリスナーメソッドも、それに応じて手直しします。

  1. private function dispatchMouseEvent(eventObject:TouchEvent):void {
  2.   var myTouch:Touch = eventObject.getTouch(stage);
  3.   if (myTouch) {
  4.     // var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  5.     switch (myTouch.phase) {
  6.       case TouchPhase.BEGAN:
            // if (instanceIsTouched(instance, myTouch)) {
  7.         if (instanceIsTouched(eventObject, myTouch)) {
  8.           pressed = true;
  9.         }
  10.         break;
  11.       case TouchPhase.ENDED:
            // if (pressed && instanceIsTouched(instance, myTouch)) {
  12.         if (pressed && instanceIsTouched(eventObject, myTouch)) {
  13.           onClick(eventObject);
  14.         }
  15.         pressed = false;
  16.         break;
  17.     }
  18.   }
  19. }
    // private function instanceIsTouched(instance:DisplayObject, myTouch:Touch):Boolean {
  20. private function instanceIsTouched(eventObject:Event, myTouch:Touch):Boolean {
      var instance:DisplayObject = getInstance(eventObject);
  21.   var mousePoint:Point = myTouch.getLocation(instance);
  22.   var touched:Boolean = myBitmapData.hitTest(zeroPoint, 0x0, mousePoint);
  23.   return touched;
  24. }
  25. private function getInstance(eventObject:Event):DisplayObject {
  26.   var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  27.   return instance;
  28. }

この直したスクリプトに、前述3つのマウス操作のメソッドを組込んだのが以下のスクリプト004です。DisplayObject.touchイベントのリスナーメソッド(dispatchMouseEvent())に、Touch.phaseプロパティとフラグのプロパティ(pressed)値に応じた3つのメソッドの呼出しが加えられています(第44〜59行目)。

スクリプト004■複数のマウス操作に応じてインスタンスのふるまいが変わる
    // ActionScript 3.0クラス定義ファイル: MySprite.as
  1. package {
  2.   import flash.display.BitmapData;
  3.   import flash.geom.Point;
  4.   import starling.display.DisplayObject;
  5.   import starling.display.Sprite;
  6.   import starling.display.Image;
  7.   import starling.textures.Texture;
  8.   import starling.events.Event;
  9.   import starling.events.TouchEvent;
  10.   import starling.events.Touch;
  11.   import starling.events.TouchPhase;
  12.   public class MySprite extends Sprite {
  13.     private var myBitmapData:BitmapData;
  14.     private var zeroPoint:Point = new Point(0, 0);
  15.     private var pressed:Boolean = false;
  16.     public function MySprite() {
  17.       addEventListener(Event.ADDED_TO_STAGE, initialize);
  18.     }
  19.     private function initialize(eventObject:Event):void {
  20.       myBitmapData = new Pen();
  21.       var myTexture:Texture = Texture.fromBitmapData(myBitmapData);
  22.       var ball:Image = new Image(myTexture);
  23.       addChild(ball);
  24.       ball.x = (stage.stageWidth - myTexture.width) / 2;
  25.       ball.y = (stage.stageHeight - myTexture.height) / 2;
  26.       ball.addEventListener(TouchEvent.TOUCH, dispatchMouseEvent);
  27.     }
  28.     private function onPress(eventObject:TouchEvent):void {
  29.       var instance:DisplayObject = getInstance(eventObject);
  30.       instance.alpha = 0.7;
  31.     }
  32.     private function onClick(eventObject:TouchEvent):void {
  33.       var instance:DisplayObject = getInstance(eventObject);
  34.       instance.y += 5;
  35.       instance.alpha = 1;
  36.     }
  37.     private function onReleaseOutside(eventObject:TouchEvent):void {
  38.       var instance:DisplayObject = getInstance(eventObject);
  39.       instance.alpha = 1;
  40.     }
  41.     private function dispatchMouseEvent(eventObject:TouchEvent):void {
  42.       var myTouch:Touch = eventObject.getTouch(stage);
  43.       if (myTouch) {
  44.         switch (myTouch.phase) {
  45.           case TouchPhase.BEGAN:
  46.             if (instanceIsTouched(eventObject, myTouch)) {
  47.               pressed = true;
  48.               onPress(eventObject);
  49.             }
  50.             break;
  51.           case TouchPhase.ENDED:
  52.             if (pressed && instanceIsTouched(eventObject, myTouch)) {
  53.               onClick(eventObject);
  54.             } else {
  55.               onReleaseOutside(eventObject);
  56.             }
  57.             pressed = false;
  58.             break;
  59.         }
  60.       }
  61.     }
  62.     private function instanceIsTouched(eventObject:Event, myTouch:Touch):Boolean {
  63.       var instance:DisplayObject = getInstance(eventObject);
  64.       var mousePoint:Point = myTouch.getLocation(instance);
  65.       var touched:Boolean = myBitmapData.hitTest(zeroPoint, 0x0, mousePoint);
  66.       return touched;
  67.     }
  68.     private function getInstance(eventObject:Event):DisplayObject {
  69.       var instance:DisplayObject = eventObject.currentTarget as DisplayObject;
  70.       return instance;
  71.     }
  72.   }
  73. }

これで、インスタンスの上でマウスボタンを押すとアルファが下がり、そのまま放せば位置が下がってアルファは戻ります。インスタンスの外でマウスボタンを放すと、位置もアルファももとのままです(図004)。マウスポインタとの重なりは、アルファを識別したビットマップのイメージで評価されます。

図004■インスタンス上でマウスボタンを押すとアルファが下がり放すと戻る
図004左 図004右


作成者: 野中文雄
更新日: 2012年8月13日 03「マウスボタンを押す操作も確かめる」を加えるとともに、他の項のスクリプトや解説も加筆・補正した。
作成日: 2012年5月29日


Copyright © 2001-2012 Fumio Nonaka.  All rights reserved.