■サンプルファイル: F-site_May15_04 (約44KB Zip/Sit)
*.flaファイルはいずれもFlash MX 2004で作成していますが、ActionScript2.fla以外は[Flash MXドキュメント(*.fla)]のフォーマットで保存しています。ActionScript 2.0クラス定義ファイルEasing.asは、テキストファイルですので、エディタ等で開くことができます。

// MovieClip: 移動するインスタンス
// MovieClipアクション
// 初期設定
onClipEvent (load) {
  var nDeceleration = 0.2;  // 減速率
  var nTargetX = _x;  // 初期水平(x)位置座標
}
// アニメーション処理
// *減速のアニメーションについては「MovieClipのターゲットパスとプロパティ」参照
onClipEvent (enterFrame) {
  _x += (nTargetX-_x)*nDeceleration;
}

// MovieClip: ボタン
// MovieClipアクション
on (release) {
  _parent.my_mc.nTargetX += 10;
}

MovieClipとonハンドラ
MovieClipインスタンスにButtonと同じonイベントハンドラアクションが設定できるのは、Flash MX以降。

// MovieClip: 移動するインスタンス
// 第1フレームアクション
// 初期設定
var nDeceleration = 0.2;
var nTargetX = _x;
// イベントハンドラメソッドを使用したアニメーション処理
this.onEnterFrame = function() {
   _x += (nTargetX-_x)*nDeceleration;
};

// _root: メインのタイムライン
// 第1フレームアクション

// アニメーションするインスタンスの処理
// MovieClip: _root.my_mc
my_mc.nDeceleration = 0.2;
my_mc.nTargetX = my_mc._x;
my_mc.onEnterFrame = function() {
   this._x += (this.nTargetX-this._x)*this.nDeceleration;
};

// ボタンの(MovieClip)インスタンスの処理
// MovieClip: _root.button_mc
button_mc.onRelease = function() {
   this._parent.my_mc.nTargetX += 10;
};

// MovieClip: 移動するインスタンス
// 第1フレームアクション
// [初期設定]=====
var nDeceleration = 0.2;
var nTargetX = _x;
// [function定義]=====
// 関数xEaseTo(): イーズアウトの開始
// 引数nX: 移動ピクセル数
function xEaseTo(nX) {
  nTargetX = _x+nX;
  this.onEnterFrame = xFrameAnimation;
}
// 関数xFrameAnimation(): アニメーション処理
// 引数: なし
function xFrameAnimation() {
  var nDistanceX = nTargetX-_x;
  if (Math.abs(nDistanceX)>0.5) {
    _x += nDistanceX*nDeceleration;
  } else {
    _x = nTargetX;
    // イベントハンドラメソッドのクリア
    delete this.onEnterFrame;
  }
  trace(_x); //  確認用
}

// MovieClip: ボタン
// MovieClipアクション
on (release) {
   _parent.my_mc.xEaseTo(10);
}

// _root: メインのタイムライン
// 第1フレームアクション

// MovieClip: _root.my_mc
// [初期設定]=====
my_mc.nDeceleration = 0.2;
my_mc.nTargetX = my_mc._x;
// [function定義]=====
function xEaseTo(nX) {
  my_mc.nTargetX = my_mc._x+nX;
  my_mc.onEnterFrame = xFrameAnimation;
}
function xFrameAnimation() {
  var nDistanceX = this.nTargetX-this._x;
  if (Math.abs(nDistanceX)>0.5) {
    this._x += nDistanceX*this.nDeceleration;
  } else {
    this._x = this.nTargetX;
    delete this.onEnterFrame;
  }
  trace(this._x);  // 確認用
}

// MovieClip: _root.button_mc
button_mc.onRelease = function() {
  this._parent.xEaseTo(10);
};

// ActionScript 2.0クラス定義ファイル: Easing.as
// class定義: MovieClipクラスを継承
class Easing extends MovieClip {
  // [プロパティ宣言]=====
  var nDeceleration:Number = 0.2;
  var nTargetX:Number;
  // [コンストラクタ関数]=====
  // インスタンス生成時に呼出される
  function Easing() {
    nTargetX = _x;
  }
  // [メソッド(function)定義]=====
  function xEaseTo(nX:Number):Void {
    nTargetX = _x+nX;
    this.onEnterFrame = xFrameAnimation;
  }
  function xFrameAnimation():Void {
    var nDistanceX:Number = nTargetX-_x;
    if (Math.abs(nDistanceX)>0.5) {
      _x += nDistanceX*nDeceleration;
    } else {
      _x = nTargetX;
      delete this.onEnterFrame;
    }
  }
}