[*1] データ型は、Functionです。したがって、Flash 8の「ActionScript 2.0リファレンスガイド」が「public callee : Object」とし、データ型をObjectのように記載しているのは誤りです。

function myFunction():Void {
   // function自身に設定されたプロパティを取出す
   var name_str:String = arguments.callee._name;
   trace(name_str);
}
// functionにプロパティを設定
myFunction._name = "myFunction";
myFunction();   // 出力: myFunction

// 階乗を計算する関数xFactorial
// [引数] n: 正の整数
function xFactorial(n:Number):Number {
  if (n<=1) {   //nが1以下であれば
    //1を返す(再帰終了)
    return 1;
  } else {   //nが1より大きければ
    //nを1マイナスして関数の再帰呼び出し
    return n*arguments.callee(--n);
    // return n*xFactorial(--n);   // 直接function名で参照も可能
  }
}
// 関数のテスト例
trace (xFactorial(5));   //出力: 120   //= 5*4*3*2*1

// 階乗を計算する関数xFactorial
// [引数] n: 正の整数。それ以外の値は前処理される
// 実際には引数の前処理を行う
function xFactorial(n:Number):Number {
  //不適切な引数の場合
  if (typeof (n) != "number" || n<0 || isNaN(n)) {
    return NaN; //エラーとしてNaNを返す
  }
  //小数点以下があれば切り捨て
  n = Math.floor(n);
  return _Factorial(n);
}
// 実際に階乗を計算する関数xFactorial
// [引数] n: 正の整数。それ以外の値は前処理される
function _Factorial(n:Number):Number {
  if (n) { //nが0以外(より大)であれば
    //nを1マイナスして関数の再帰呼び出し
    return n*arguments.callee(--n);
  } else { //nが0であれば
    //1を返す(再帰終了)
    return 1;
  }
}

[*2] サンプルスクリプトは、ActionScript 2.0のシンタックスを用いています。ActionScript 1.0で使用する場合には、型指定を削除してください。

[*3] ActionScriptは256レベル以上の再帰を行うと、つぎのようなエラーになります。