// フレームアクション
// 空のMovieClipインスタンスmy_mcを配置

1. my_mc.graphics.lineStyle(2, 0x0000FF);
2. my_mc.graphics.beginFill(0x00FFFF);
3. my_mc.graphics.drawCircle(0, 0, 50);
4. my_mc.graphics.endFill();

インスタンスに備わるGraphicsオブジェクトを取出して、そのメソッドで描画した。

// フレームアクション
// 空のMovieClipインスタンスmy_mcを配置

1. var myGraphics:Graphics = my_mc.graphics;   // 初めにプロパティのオブジェクトを変数に代入
   // 変数のインスタンスを操作する
2. myGraphics.lineStyle(2, 0x0000FF);
3. myGraphics.beginFill(0x00FFFF);
4. myGraphics.drawCircle(0, 0, 50);
5. myGraphics.endFill();

3つのインスタンスは水平にスクロールし、ステージの端を超えると反対側の端から表れる。

// フレームアクション
// 3つのMovieClipインスタンス(my0_mc〜my2_mc)を配置

1. var nWidth:int = stage.stageWidth;
2. var mcs_array:Array = [my0_mc, my1_mc, my2_mc];   // インスタンスの参照を配列に納める
3. addEventListener(Event.ENTER_FRAME, xScroll);
4. function xScroll(eventObject:Event):void {
5.   for (var i:uint = 0; i < mcs_array.length; i++) {   // ループするたびにプロパティを調べる
       // 同じインスタンスを何度も配列から取出す
6.     mcs_array[i].x += 5;
7.     if (nWidth < mcs_array[i].x) {
8.       mcs_array[i].x -= nWidth;
9.     }
10.   }
11. }

// フレームアクション
// 3つのMovieClipインスタンス(my0_mc〜my2_mc)を配置

1. var nWidth:int = stage.stageWidth;
2. var mcs_array:Array = [my0_mc, my1_mc, my2_mc];   // インスタンスの参照を配列に納める
3. var nLength:uint = mcs_array.length;   // プロパティ値を変数にとっておく
4. addEventListener(Event.ENTER_FRAME, xScroll);
5. function xScroll(eventObject:Event):void {
6.   for (var i:uint = 0; i < nLength; i++) {
7.     var my_mc:MovieClip = mcs_array[i];   // インスタンスを型指定した変数に入れる
       // 変数のインスタンスを操作する
8.     my_mc.x += 5;
9.     if (nWidth < my_mc.x) {
10.       my_mc.x -= nWidth;
11.     }
12.   }
13. }

Tips 01-04-001■型指定した変数にはコードヒントが働く
インスタンスを配列エレメントとして取出したときと異なり、型指定した変数に入れればコードヒントが働きます(図01-04-003)。

インスタンスのMatrix3Dオブジェクトに対して、平行移動と回転のメソッドを呼出す。

// フレームアクション
// MovieClipインスタンスmy_mcを配置

1. var my_mc:MovieClip;
2. var nX:Number = my_mc.x;
3. var nY:Number = my_mc.y;
4. my_mc.z = 0;   // 3次元の操作を加える
   // 初めにプロパティのオブジェクトを変数に代入
5. var myMatrix3D:Matrix3D = my_mc.transform.matrix3D;
6. my_mc.addEventListener(Event.ENTER_FRAME, xRotate);
7. function xRotate(eventObject:Event):void {
     // 変数のインスタンスを操作する
8.   myMatrix3D.appendTranslation(-nX, -nY, 0);
9.   myMatrix3D.appendRotation(5, Vector3D.Y_AXIS);
10.   myMatrix3D.appendTranslation(nX, nY, 0);
11. }

Tips 01-04-002■DisplayObject.transformから得られるTransform.matrix3Dはデフォルト値がnull
インスタンスのプロパティDisplayObject.transformから得られるTransform.matrix3Dは、デフォルトでは値がnullになっています。オーサリング時またはスクリプトで3次元の操作を加えることにより、Matrix3Dオブジェクトがつくられます。

上記スクリプトでDisplayObject.zプロパティを操作しているのは、そのためです。z座標値はデフォルトが0ですので、見た目には変わりません。けれど、この設定によりインスタンスにMatrix3Dオブジェクトができあがるのです。

Basics 01-04-001■Matrix3Dクラスによる3次元空間座標の扱い
Matrix3Dクラスの扱いについて詳しくは、gihyo.jp連載「ActionScript 3.0で始めるオブジェクト指向スクリプティング」第35回「Matrix3Dクラスによる座標変換」<http://gihyo.jp/dev/serial/01/as3/0035>以降、およびAdobeデベロッパーセンター「Matrix3Dクラス − 変換行列2」<http://www.adobe.com/jp/devnet/flash/articles/matrix3d_class.html>をお読みください。

// フレームアクション
// MovieClipインスタンスmy_mcを配置
1. var my_mc:MovieClip;
2. var nX:Number = my_mc.x;
3. var nY:Number = my_mc.y;
   // 初めにプロパティのオブジェクトを変数に代入
4. var myMatrix:Matrix = my_mc.transform.matrix;
5. my_mc.addEventListener(Event.ENTER_FRAME, xRotate);
6. function xRotate(eventObject:Event):void {
     // 変数のインスタンスを操作する
7.   myMatrix.translate(-nX, -nY);
8.   myMatrix.rotate(0.05);
9.   myMatrix.translate(nX, nY);
10. }

// フレームアクション
// MovieClipインスタンスmy_mcを配置

1. var my_mc:MovieClip;
2. var nX:Number = my_mc.x;
3. var nY:Number = my_mc.y;
   // 初めにプロパティのオブジェクトを変数に代入
4. var myMatrix:Matrix = my_mc.transform.matrix;
5. my_mc.addEventListener(Event.ENTER_FRAME, xRotate);
6. function xRotate(eventObject:Event):void {
7.   // 変数のインスタンスを操作する
8.   myMatrix.translate(-nX, -nY);
9.   myMatrix.rotate(0.05);
10.   myMatrix.translate(nX, nY);
11.   my_mc.transform.matrix = myMatrix;   // Matrixオブジェクトをプロパティに再設定
12. }

インスタンスのMatrixオブジェクトに対して、平行移動と回転のメソッドを呼出す。

Basics 01-04-002■Matrixクラスによる2次元平面座標の扱い
Matrixクラスの扱いについて詳しくは、Adobeデベロッパーセンター「Matrixクラス − 変換行列1」<http://www.adobe.com/jp/devnet/flash/articles/matrix_class.html>をお読みください。

Tips 01-04-003■オブジェクトの参照か複製かの違い
Transform.matrix3Dプロパティは、Matrix3Dオブジェクトの参照をやり取りします。つまり、変数に入れたMatrix3DオブジェクトをTransform.matrix3Dプロパティに設定すれば、変数とプロパティとは同じオブジェクトを参照します。したがって、MovieClipインスタンスmy_mcのあるタイムラインにつぎのフレームアクションを書くと、trueが[出力]されます。

var myMatrix3D:Matrix3D = new Matrix3D(); my_mc.transform.matrix3D = myMatrix3D; trace(myMatrix3D == my_mc.transform.matrix3D);   // 出力: true

それに対して、Transform.matrixプロパティでは、複製したMatrixオブジェクトが読み書きされます。そのため、以下のスクリプトでは、変数とプロパティは同じ内容の(複製された)異なるMatrixオブジェクトを参照するので、falseが[出力]されることになるのです。

var myMatrix:Matrix = new Matrix(); my_mc.transform.matrix = myMatrix; trace(myMatrix == my_mc.transform.matrix);   // 出力: false