1. for (var i:Number = 0; i < 10; i++) {
2.   // 処理内容
3. }

1. for (var i:uint = 0; i < 10; i++) {
2.   // 処理内容
3. }

1. for (var i:uint = 0; i < my_array.length; i++) {   // 継続条件にプロパティを使う
2.   // 処理内容
3. }

1. var nLength:uint = my_array.length;   // プロパティ値を変数にとる
2. for (var i:uint = 0; i < nLength; i++) {   // 継続条件には変数を使う
3.   // 処理内容
4. }

インスタンスがそれぞれ水平にスクロールし、ステージの端を超えると反対側の端から表れる。

[ライブラリ]パネルのメニューから[プロパティ]で[シンボルプロパティ]ダイアログボックスを開き、[リンケージ]の[ActionScript用に書き出し]をチェックして、[クラス]にクラス名MyClassを入力する。

Tips 03-01-001■クラス定義の自動生成
この例の場合、クラスを定義する必要はありません。定義されていないクラス名を[シンボルプロパティ]ダイアログボックスのクラスに設定すると、下図03-01-003のような警告のダイアログボックスが表れます。[OK]ボタンをクリックすれば、MovieClipクラスを継承した空の(追加するプロパティやメソッドのない)クラスが自動的につくられます。

// フレームアクション

1. var nCenterY:Number = stage.stageHeight / 2;
2. var nWidth:int = stage.stageWidth;
3. var mcs_array:Array = new Array();
4. var nCount:uint = 5;
5. var nSpeed:uint = 5;
6. xInitialize();
7. function xInitialize():void {
8.   for (var i:Number = 0; i < nCount; i++) {
       // 配列エレメントを操作する
9.     mcs_array[i] = new MyClass();
10.     mcs_array[i].x = nWidth * i / nCount;
11.     mcs_array[i].y = nCenterY;
12.     addChild(mcs_array[i]);
13.   }
14.   addEventListener(Event.ENTER_FRAME, xScroll);
15. }
16. function xScroll(eventObject:Event):void {
17.   for (var i:Number = 0; i < mcs_array.length; i++) {   // 継続条件にプロパティを使う
        // 配列エレメントを操作する
18.     mcs_array[i].x += nSpeed;
19.     if (nWidth < mcs_array[i].x) {
20.       mcs_array[i].x -= nWidth;
21.     }
22.   }
23. }

// フレームアクション

1. var nCenterY:Number = stage.stageHeight / 2;
2. var nWidth:int = stage.stageWidth;
3. var mcs_array:Array = [];
4. var nCount:uint = 5;
5. var nSpeed:uint = 5;
6. xInitialize();
7. function xInitialize():void {
8.   var nSpace:Number = nWidth / nCount;
9.   for (var i:uint = 0; i < nCount; i++) {
10.     var my_mc:MovieClip = new MyClass();   // オブジェクトをローカル変数にとる
        // ローカル変数のオブジェクトを操作する
11.     my_mc.x = nSpace * i;
12.     my_mc.y = nCenterY;
13.     mcs_array[i] = my_mc;
14.     addChild(my_mc);
15.   }
16.   addEventListener(Event.ENTER_FRAME, xScroll);
17. }
18. function xScroll(eventObject:Event):void {
19. var nLength:uint = mcs_array.length;   // Array.lengthプロパティの値をローカル変数にとる
20.   for (var i:uint = 0; i < nLength; i++) {   // 継続条件にローカル変数を使う
21.     var my_mc:MovieClip = mcs_array[i];   // 配列エレメントをローカル変数にとる
        // ローカル変数のオブジェクトを操作する
22.     var nX:Number = my_mc.x + nSpeed;   // プロパティ値をローカル変数にとる
23.     if (nWidth < nX) {
24.       nX -= nWidth;
25.     }
26.     my_mc.x = nX;   // ローカル変数の値をプロパティに設定する
27.   }
28. }

Tips 03-01-002■Arrayインスタンスは配列アクセス演算子[]でつくる
後述03-05「Arrayインスタンスはコンストラクタでなくリテラルでつくる」のとおり、Arrayインスタンスをつくるのはコンストラクタを呼出すより配列アクセス演算子[]による方が処理は速いです。前掲フレームアクションの「悪い例」と「よい例」では、この配列(mcs_array)のつくり方も違っています。

○Arrayインスタンスはコンストラクタメソッドより速くつくる方法がある

var mcs_array:Array = new Array();

◎Arrayインスタンスは配列アクセス演算子[]の方がコンストラクタより速くつくれる

var mcs_array:Array = [];

Comparing local variable with property - wonderfl build flash online

// フレームアクション

1. var my_array:Array = [];   // タイムライン変数
2. var nCount:uint = 1000;   // タイムライン変数
3. iterateArray();
4. function iterateArray():void {   // 関数定義
5.   for (var i:uint = 0; i < nCount; i++) {   // 継続条件にタイムライン変数を用いる
6.     my_array[i] = i;   // タイムライン変数の配列にエレメントを加える
7.   }
8. }

// フレームアクション

1. var my_array:Array = [];
2. var nCount:uint = 1000;
3. iterateArray();
4. function iterateArray():void {   // 関数定義
5.   var _array:Array = my_array;   // ローカル変数
6.   var count:uint = nCount;   // ローカル変数
7.   for (var i:uint = 0; i < count; i++) {   // 継続条件にローカル変数を用いる
8.     _array[i] = i;   // ローカル変数の配列にエレメントを加える
9.   }
10. }

Tips 03-01-003■Array.lengthプロパティの値はローカル変数に入れる
前述03-01-02「Array.lengthプロパティの値は予め変数にとる」というのは、forループの処理が関数内で行われる場合には、プロパティ値をローカル変数に入れることになります。すると、処理はさらに速まります。

// クラス定義ファイル: Test.as

1. package {
2.   import flash.display.Sprite;
3.   public class Test extends Sprite {
4.     private var my_array:Array = [];   // インスタンスプロパティ
5.     private var nCount:uint = 1000;   // インスタンスプロパティ
6.     public function Test() {
7.       iterateArray();
8.     }
9.     private function iterateArray():void {
10.       var _array:Array = my_array;   // ローカル変数
11.       var count:uint = nCount;   // ローカル変数
12.       for (var i:uint = 0; i < count; i++) {
13.         _array[i] = i;
14.       }
15.     }
16.   }
17. }

「Flash Platform のパフォーマンスの最適化」「その他の最適化」
BeInteractive!「ループの最適化」

Assigning values to several types of variables - wonderfl build flash online

Iterating elements in member and local variables - wonderfl build flash online