たとえば、以下のフレームアクションを実行すると、[出力]ウィンドウに'undefined'と表示されます。

//[テスト用スクリプト]
// _root: MovieClipインスタンスをダイナミックに配置
// フレームアクション
this.attachMovie("mySymbol", "my_mc", 1);
trace(this.my_mc.xCall);  // 出力: undefined
this.my_mc.xCall();  // 実行されない

// MovieClip: 配置されるムービークリップシンボル
// リンケージ識別子: mySymbol
// 第1フレームアクション
function xCall() {
  trace(this);  // 確認用にターゲットパスを出力
}

なお、メソッド実行直後でも、配置されたMovieClip自体はすでに生成されています。このとき、MovieClipの定義済みのプロパティ(たとえば'MovieClip._x')やメソッド(たとえば'MovieClip.gotoAndPlay')は、設定したり呼出すことが可能です。

Flash MXから実装されたイベントハンドラメソッド'MovieClip.onEnterFrame'を使って、フレーム待ちの処理を行うことができます。

//[テスト用スクリプト]
// _root: MovieClipインスタンスをダイナミックに配置
// フレームアクション
this.attachMovie("mySymbol", "my_mc", 1);
this.onEnterFrame = function() {  // [1]イベントハンドラメソッドを定義
  this.my_mc.xCall();  // [2]'function'を呼出し
  delete this.onEnterFrame;  // [3]イベントハンドラメソッドの定義をクリア
};

// MovieClip: 配置されるムービークリップシンボル
// リンケージ識別子: mySymbol
// 第1フレームアクション
function xCall() {
  trace(this);  // 確認用にターゲットパスを出力
}

[1] 'function'の呼出しを1フレーム待たせるために、処理を'MovieClip.onEnterFrame'イベントハンドラメソッドに設定しています。イベントハンドラメソッドには、処理を定義した'function'名または「名前のない関数」を設定します(イベントハンドラメソッドについて、詳しくは前掲『モーショングラフィックスで学ぶActionScript − Flash MX −』p.110〜「4.7 イベントを第1フレームで処理する」参照)。ここでは、後者によりました。

[2] 'MovieClip.attachMovie'メソッドで配置したMovieClipの'function'を呼出します。配置後最初にフレームが描画されるときに、イベントハンドラメソッド'MovieClip.onEnterFrame'の処理は実行されます。したがって、配置から1フレーム遅れた処理になります。

[注記] クラスに定義したメソッド(中・上級者向け情報)
'Object.registerClass'メソッドを使ってムービークリップシンボルにクラス定義をした場合、クラスのメソッドは'MovieClip.attachMovie'メソッドでMovieClipを配置した直後でも呼出すことができます。

//[テスト用スクリプト]
// _root: MovieClipインスタンスをダイナミックに配置
// フレームアクション
// クラス定義
function MyClass() {}
MyClass.prototype = new MovieClip();
MyClass.prototype.xCall = function() {
  trace(this);
};
Object.registerClass("mySymbol", MyClass);
// MovieClipの配置
this.attachMovie("mySymbol", "my_mc", 1);
trace(this.my_mc.xCall);  // 出力: [type Function]
this.my_mc.xCall();  // 実行される

// MovieClip: 配置されるムービークリップシンボル
// リンケージ識別子: mySymbol
// *前記と同様のためスクリプトは省略

関連項目
MovieClip.duplicateMovieClipで複製したMovieClipのfunctionが実行されない