import mx.utils.Delegate;
compInstance.addEventListener(イベント名, Delegate.create(スコープオブジェクト, 関数));

[*1]addEventListener()メソッドの第2引数に関数を指定すると、リスナー関数はイベントを配信するコンポーネントインスタンスのスコープで呼出されます。以下のサンプルスクリプトでは、リスナー関数clickHandlerがButtonコンポーネントインスタンスmy_btnのスコープで呼出されるので、関数ブロック({})内のthisはmy_btnを参照します。したがって、thisを参照してタイムライン上のプロパティにアクセスしようとすれば、undefinedが返されます。

// [出力]パネルの表示
_level0.my_btn,undefined,_level0.my_btn

もっとも、タイムライン上であれば、thisを参照せずデフォルト参照を使うことで対応できます。実際に問題になるのは、後述「2. 関数のスコープの委譲」のようにクラスでメソッド(関数)をリスナーに指定したい場合でしょう。

// import mx.utils.Delegate;  // [*2]
import mx.controls.Button;
import mx.controls.CheckBox;
class Cart {
  var myCheckBox_chb:CheckBox;
  var myButton_btn:Button;
  function onLoad() {
    myCheckBox_chb.addEventListener("click", this);
    myButton_btn.addEventListener("click", this);
  }
  function click(eventObj:Object) {
    switch (eventObj.target) {
    case myButton_btn :
      // メッセージを配信するインスタンス名と
      // イベントタイプを[出力]パネルに表示
      trace(eventObj.target+":"+eventObj.type);
      break;
    case myCheckBox_chb :
      trace(eventObj.target+":"+eventObj.type);
      break;
    }
  }
}

import mx.utils.Delegate;
import mx.controls.Button;
import mx.controls.CheckBox;
class Cart {
  var myCheckBox_chb:CheckBox;
  var myButton_btn:Button;
  function onLoad() {
    myCheckBox_chb.addEventListener("click", Delegate.create(this, chb_onClick));
    myButton_btn.addEventListener("click", Delegate.create(this, btn_onClick));  // [*3]
  }
  // 同一のイベントを処理する異なったふたつの関数
  function chb_onClick(eventObj:Object) {
    // メッセージを配信するインスタンス名と
    // イベントタイプを[出力]パネルに表示
    trace(eventObj.target+":"+eventObj.type);
    // FLAファイルのなかのCartクラスが関連づけられたシンボルの
    // インスタンスへの絶対パスを[出力]パネルに表示
    trace(this);
  }
  function btn_onClick(eventObj:Object) {
    trace(eventObj.target+":"+eventObj.type);
    trace(this);
  }
}

[*3]Delegateクラスを使って作成・登録したリスナーを、イベントを配信するインスタンスから削除するには、予めリスナーへの参照を取得しておく必要があります。なお、Delegate.create()メソッドは、関数(Function型データ)を返します。

import mx.controls.Button;
import mx.controls.CheckBox;
class Cart {
  var myCheckBox_chb:CheckBox;
  var myButton_btn:Button;
  // chb_onClick関数からアクセスする変数を定義
  var i:Number = 10;
  function onLoad() {
    myCheckBox_chb.addEventListener("click", chb_onClick);
  }
  function chb_onClick(eventObj:Object) {
    // 変数iにアクセスして10が出力できるように思えます
    // しかし[出力]バネルにはundefinedが表示されます
    // 関数のスコープがiを定義したCartインスタンスではないからです
    trace(i);
  }
}

import mx.utils.Delegate;
import mx.controls.Button;
import mx.controls.CheckBox;
class Cart {
  var myCheckBox_chb:CheckBox;
  var myButton_btn:Button;
  // chb_onClick関数からアクセスする変数を定義
  var i:Number = 10;
  function onLoad() {
    myCheckBox_chb.addEventListener("click", Delegate.create(this, chb_onClick));
  }
  function chb_onClick(eventObj:Object) {
    // [出力]バネルには10が表示されます
    // 関数のスコープがCartインスタンスに指定されているからです
    trace(i);
  }
}