import mx.controls.ComboBox;
// ComboBoxインスタンスexistingComboBoxを予め配置
var existingComboBox:ComboBox;
var nAmount:Number = 3;   // ComboBoxに設定する項目数
// ComboBoxのイベントリスナー登録[*1]
existingComboBox.addEventListener("change", this);
// ComboBoxインスタンスに項目を設定
function init() {
  for (var i:Number = 0; i<nAmount; ++i) {
    existingComboBox.addItem("item"+i, i);
  }
}
// ComboBoxからリスナーとして呼出されるコールバック関数
function change(eventObject:Object):Void {
  var selectedValue:Number = eventObject.target.value;
  trace(selectedValue);   // 選択された項目のデータ(番号)を出力
}
init();   // 関数の呼出し

[*1] イベントリスナーには、別途のリスナーオブジェクトを作成せず、スクリプトを設定したMovieClipインスタンス自身(this)を登録しています。このMovieClipをスクリプトと合わせて、ちょうどコンポーネントのような「パーツ」として捉えるデザインです。スクリプトをクラスとして定義しようとする場合には、このデザインの方が移行しやすいでしょう。

import mx.controls.ComboBox;
class UseComponent extends MovieClip {
  var existingComboBox:ComboBox;
  function UseComponent() {
    init();
  }
  function init() {
    trace(existingComboBox);   // 出力: _level0.my_mc.existingComboBox
    trace(existingComboBox instanceof ComboBox);   // 出力: false
    trace(existingComboBox instanceof MovieClip);   // 出力: true
    trace(existingComboBox.addItem);   // 出力: undefined
  }
}

import mx.controls.ComboBox;
class UseComponent extends MovieClip {
  var existingComboBox:ComboBox;
  var nAmount:Number = 3;
  function UseComponent() {
    // init();
  }
  // function init() {
  function onLoad() {
    for (var i:Number = 0; i<nAmount; ++i) {
      existingComboBox.addItem("item"+i, i);
    }
    existingComboBox.addEventListener("change", this);
  }
  function change(eventObject:Object):Void {
    var selectedValue:Number = eventObject.target.value;
    trace(selectedValue);
  }
}

[*2] MovieClip.onLoadイベントハンドラメソッドを使うべき数少ない実用上の例です。クラスの通常の初期化の処理は，コンストラクタ関数に記述すれば足ります。また、フレームアクションやMovieClipアクションなど、クラスでなくムービー中に記述した場合、それらのスクリプトはMoiveClip.onLoadイベントがすでに発生した後に処理されるため、コールバック関数を設定しても呼出されません(「MovieClip.onLoadイベントハンドラメソッド」参照)。

import mx.controls.ComboBox;
// class UseComponent extends MovieClip {
class UseComponent extends mx.core.UIObject {
  var existingComboBox:ComboBox;
  var nAmount:Number = 3;
  function UseComponent() {}
  // function onLoad() {
  function draw() {
    for (var i:Number = 0; i<nAmount; ++i) {
      existingComboBox.addItem("item"+i, i);
    }
    existingComboBox.addEventListener("change", this);
  }
  function change(eventObject:Object):Void {
    var selectedValue:Number = eventObject.target.value;
    trace(selectedValue);
  }
}

[*3] UIObjectから呼出されるメソッド(イベント)については、Flash 8オンラインヘルプ[Flash コンポーネントガイド]�> [コンポーネントの作成] > [ActionScriptクラスファイルの作成] > [コア関数について]をご参照ください。

なお、init()も、UIObjectから独自に呼出されるメソッドに含まれます。ですから、コンストラクタ関数から呼出すと、二重の呼出しになってしまうので注意しましょう。

[*4] draw()は、MovieClip.onLoadイベントよりも後に呼出されます。