Platform: All
Version: Flash MX 2004

3.1 クラスの作成と使用について
すでに解説したとおり(「2.2 クラスファイルの作成」参照)、クラスは2つの部分から構成されます。「宣言」(declaration)と「本体」(body)です。クラス宣言は最低限、classステートメントと、それに続けてクラス名となる識別子、そして始まりと閉じの中括弧({})で構成されます。中括弧内は、すべてクラス本体になります。その例は、つぎのとおりです。

class className {
  // クラス本体
}

クラスは、ActionScript(AS)ファイル内でのみ定義できます。たとえば、クラスをFLAファイルのフレームアクションで定義することはできません。

クラス名は、識別子でなければなりません。つまり、(訳者註: 使用する文字はすべて半角で)最初のひと文字は英字かアンダースコア(_)、ドル記号($)で始まり、続く文字列は半角英数字かアンダースコア、ドル記号で構成される必要があります。またクラス名は、それを記述したASファイルの名前と、大文字小文字の別も含めて、正確に一致しなければなりません。つぎの例のようにShapeというクラスを作成したら、クラス定義を記述したASファイルにはShape.asという名前をつける必要があるのです。

// Shape.asファイル
class Shape {
  // Shapeクラス本体
}

作成したすべてのASクラスファイルは、所定のクラスパス(classpath)フォルダのいずれかに保存しなければなりません。クラスパスフォルダは、スクリプトをコンパイルするときにFlashがクラス定義を検索する対象となります。そのひとつは、クラスを参照するFLAファイルが保存されているフォルダです(詳しくは、「6. クラスパスの考え方」参照)。

多くのクラスを作成する場合、「パッケージ」を用いてクラスファイルを管理します。パッケージはひとつ以上のクラスファイルを格納したディレクトリで、指定されたクラスパスディレクトリに納められます。クラス名は、それが宣言されたファイルを完全に指定する(fully qualified)必要があります。つまり、クラス名には、それが保存されているディレクトリが反映されなければなりません。

たとえば、myClasses.education.currirulum.RequiredClassという名前のクラスは、パッケージmyClasses/education/currirulumに保存します。RequiredClass.asファイルの中で、クラスはつぎのように宣言されます。

class myClasses.education.curriculum.RequiredClass {
}

このため、パッケージの構造は、クラスを作成する前に検討しておくことをお勧めします。それを怠って、クラスファイルを作成後に移動することになった場合、クラス宣言のステートメントを新たな場所に合わせて修正しなければならなくなります。

3.2 コンストラクタ関数
クラスの「コンストラクタ」(constructor)は特別な関数で、new演算子を使ってクラスのインスタンスを作成すると、自動的に呼出されます。コンストラクタ関数は、それを記述したクラスと同じ名前にします。たとえば、前に作成したPersonクラスには、以下のコンストラクタ関数がありました。

// Personクラスコンストラクタ関数
function Person(myName:String, myAge:Number) {
  this.name = myName;
  this.age = myAge;
}

コンストラクタ関数が明示的に宣言されていないとき、つまりクラスと名前の一致する関数を作成していない場合は、コンパイラが自動的に空のコンストラクタ関数を生成します。

クラスは、コンストラクタ関数をひとつだけもつことができます。コンストラクタ関数の多重定義(overload)は、ActionScript 2.0では許されていません。

コンストラクタ関数には、戻り値の型指定はできません。

[注] thisキーワードは、ActionScript 2.0のクラス定義では必要とされません。コンパイラが参照を解析して、バイトコードにthisを加えるからです。しかし、thisを用いることで、コードが読みやすくなります。詳しくは、Flash MX 2004オンラインヘルプで[ActionScriptユーザーガイド] > [ActionScriptの基礎] > [ベストプラクティスの使用] > [ActionScriptのコーディング規則] > [スコープの使用]の「thisキーワードの使用」をご参照ください。

3.3 プロパティとメソッドの作成
クラスのメンバは、プロパティ(変数宣言)とメソッド(関数宣言)とで構成されます。すべてのプロパティとメソッドは、クラス本体(中括弧{}内)に宣言する必要があります。そうしないと、コンパイル時にエラーが発生します。

クラス内でなおかつ関数の外に宣言された変数は、クラスのプロパティになります。たとえば、つぎの例に示すように、前述「クラスの使用 − シンプルな例」で採上げたPersonクラスには、2つのプロパティageとnameがあり、それぞれNumberとStringに型指定されていました。

class Person {
  var age:Number;
  var name:String;
}

同様にクラス内に宣言された関数は、クラスのメソッドになります。Personクラスの例では、getInfo()というメソッドをひとつ作成しました[*1]。

class Person {
  var age:Number;
  var name:String;
  function getInfo():Void {
    // getInfo()メソッドの定義
  }
}

クラス定義におけるthisキーワードの使用については、前述3.3の[注]をご参照ください。

3.4 メンバアクセスの制御
デフォルトでは、クラスのプロパティまたはメソッドは他のクラスすべてからアクセスが可能です。クラスのすべてのメンバは、デフォルトではpublicです。しかし、クラスのデータやメソッドが、他のクラスからアクセスできないようにしたい場合もあります。それらのメンバは、privateにする必要があります。privateのメンバは、それらを宣言あるいは定義したクラスからのみアクセスすることができます。

3.5 プロパティのインライン初期化
プロパティは、インラインで初期化できます。つまり、それらを宣言するときに、つぎのようにデフォルト値を設定することが可能です。

class Person {
  var age:Number = 50;
  var name:String = "Jogn Doe";
}

プロパティをインラインで初期化するとき、代入の右辺の式は「コンパイル時定数」(compile-time constant)でなければなりません。つまりその式は、ランタイムに設定あるいは定義される値を参照することはできません。コンパイル時定数とは、ストリングリテラルや数値、ブール(論理)値、null、undefinedなどです。また、ArrayやBoolean、Number、Object、Stringといった定義済みクラスのコンストラクタ関数も含まれます。

たとえば、以下のクラス定義は、いくつかのプロパティをインライン初期化しています。

class CompileTimeTest {
  var foo:String = "my foo"; // OK
  var bar:Number = 5; // OK
  var bool:Boolean = true; // OK
  var name:String = new String("Jane"); // OK
  var who:String = foo; // OK。fooは定数です
  var whee:String = myFunc(); // エラー! コンパイル時定数の式ではありません
  var lala:Number = whee; // エラー! コンパイル時定数の式ではありません
  var star:Number = bar + 25; // OK。barも25も定数です

  function myFunc():String {
    return "Hello world";
  }
}

この原則は、インスタンス変数(クラスの各インスタンスにコピーされる変数)[*5]にのみ適用され、クラス変数(クラス自身に帰属する変数)には当てはまりません。これらの変数について、詳しくは「4. インスタンスとクラスのメンバ」をご参照ください。

3.6 サブクラスの作成
オブジェクト指向プログラミングでは、サブクラスはプロパティやメソッドを、スーパークラスと呼ばれる他のクラスから継承します。こうした関係を2つのクラス間で構築するには、classステートメントにextends節を使用します。スーパークラスを指定するには、つぎのようなシンタックスを使用します。

class SubClass extends SuperClass {}

SubClassに指定したクラスは、スーパークラスに定義されたすべてのプロパティとメソッドを継承します。たとえば、Mammalクラスを作成して、すべてのほ乳類(mammal)に共通のプロパティとメソッドを定義したとします。MammalクラスのバリエーションとしてMarsupial(有袋動物)といったクラスを作成するには、Mammalクラスを拡張(extends)します。つまり、Mammalクラスのサブクラスを作成するのです。

class Marsupial extends Mammal {}

サブクラスは、すべてのプロパティとメソッドをスーパークラスから継承します。それらのプロパティやメソッドには、privateキーワードを使用してプライベート宣言されたものも含まれます(private変数について、詳しくは次節「3.4 メンバアクセスの制御」をご参照ください)。

独自に作成したクラスも、拡張可能です。また、XMLやSound、MovieClipクラスといったActionScriptの定義済みクラスも、同じように継承できます(TextFieldクラスまたは、MathやKey、Mouseなどの静的クラスは継承できません)。定義済みのActionScriptクラスを拡張すると、そのサブクラスはすべてのメソッドやプロパティをその定義済みクラスから継承します。

たとえば、以下のコードはクラスJukeBoxを定義して、定義済みのSoundクラスを拡張しています。このクラスには、songListという配列とplaySong()というメソッドが定義されています[*6][*7]。playSong()メソッドは、loadSoundメソッドを呼出して、音楽を再生します。loadSoundメソッドは、Soundクラスから継承したものです。

class JukeBox extends Sound {
  var songList:Array = new Array("beathoven.mp3", "bach.mp3", "mozart.mp3");
  function playSong(songID:Number):Void {
    this.loadSound(songList[songID], true);
  }
}

サブクラスのコンストラクタ関数でsuper()の呼出しを行っていない場合、コンパイラは自動的に直接のスーパークラスのコンストラクタに対する呼出しを生成します。この呼出しは、コンストラクタ関数の最初のステートメントとして、引数なしに実行されます。そのスーパークラスにコンストラクタがなければ、コンパイラは空のコンストラクタ関数を作成し、サブクラスからその呼出しを生成します。しかし、スーパークラス(訳者註: のコンストラクタ)が定義の中で引数を取る場合には、サブクラスにコンストラクタを作成し、スーパークラスを必要な引数つきで呼出す必要があります。

多重継承(multiple inheritance)あるいは複数のクラスを継承することはできません。しかし、複数のクラスを結果として継承することは、そのそれぞれにextendsステートメントを使用することで可能になります。

// 使用不可
class C extends A, B {}
// 使用可能
class B extends A {}
class C extends B {}

また、インタフェースを使えば、限定されたかたちで多重継承を実現することもできます。詳しくは、「1.4 インタフェース」および「5. インタフェースの作成と使用」をご参照ください。

出典
Flash MX 2004 Using ActionScript: Creating and using classesより邦訳。

_____